Bonjour je cale sur une macro pour l’envoie d’un mail sur l’agenda d’Outlook via un bouton exel .
J’ai commencer un code et je suis passer en language HTML pour la signature mais je n’arrive pas à trouver la ligne de commande pour le transformer en .ics
Vous mon code
Sub ParametreMessageOutlook()
'Déclaration des variables
Dim MaMessagerie As Object
Dim MonMessage As Object
Dim MaSignature As String
Dim MonFichier As String
' On affecte les variables de type objet - initialisation des variable objets - SET
Set MaMessagerie = CreateObject("Outlook.Application")
Set MonMessage = MaMessagerie.CreateItem(0)
'On affiche le mail
MonMessage.Display
'On récupère la signature
MaSignature = MonMessage.htmlbody
'on constuit le message
With MonMessage
'l'adresse du destinataire
.to = "toto@toto.fr"
' On affiche l'objet du mail
.Subject = "Demande de congés"
'On affiche le corp du mail
.htmlbody = "Bonjour, " & "<br>" & _
"Voici ma demande de congés pour la période suivante" & Sheets("Feuil1").Range("B12") & "<br>" & _
"</ul>" & MaSignature
.Display
End With
End Sub
si quelqu’un me me donner un coup de main.
En vous remerciant par avance
j’ai créer un planning de congés sous Excel
je souhaiterai avec un bouton cliquer dessus et que cela génère un mail qui incrémente le calendrier Outlook de la personne as qui on envoie le mail
Je pense comprendre un peu mieux votre demande, voici du code
En fait il faut envoyer un genre de RDV à la personne
Option Explicit
Const olAppointmentItem As Long = 1
Const OlMeeting As Long = 1
Const olFormatHTML As Long = 2
Sub RappelOutlook()
' Ajouter un nouveau rendez-vous.
Dim ObjOl As Object, ObjItem As Object
Dim Lig As Long, Sujet As String, Détail As String
Dim DebDate As String, FinDate As String, StrStamp As String
Dim Rappel As Single
' Initalisation
DebDate = "22/11/2021 08:00"
FinDate = "27/11/2021 17:00"
' Créer l'instance OUTLOOK
Set ObjOl = CreateObject("outlook.application")
' Créer l'instance pour le RDV
Set ObjItem = ObjOl.CreateItem(olAppointmentItem)
' Si tout est OK, on créé un RDV
With ObjItem
.Display ' Pour avoir la signature
.BodyFormat = olFormatHTML
.Body = "Bonjour," & vbNewLine _
& "Voici ma demande de congés pour la période suivante" & Sheets("Feuil1").Range("B12") & vbNewLine _
& "Cordialement"
.Start = DebDate
.End = FinDate
.Location = "Montargis"
.ReminderMinutesBeforeStart = 480
.ReminderSet = True
.Subject = "Formation"
.MeetingStatus = OlMeeting
' Participant(s) obligatoire(s)
.RequiredAttendees = "infopassion@free.fr"
' participants optionnel à la réunion
.OptionalAttendees = "optionnel@societe.com"
.Send
End With
' Libérez la variable objet Outlook.
Set ObjOl = Nothing: Set ObjItem = Nothing
End Sub
