Correction formule de calcul

Excel
1

Bonjour,

j’ai un fichier pour les pointages de mes horaires et souhaite avoir le cumul en fin de semaine (le vendredi) mais j’ai un message d’erreur que je n’arrive pas à identifier, pourriez-vous m’aider s’il vous plait ?

voici la formule utilisée :

=SI(E30=« »;« »;
VALEUR(SUBSTITUE(E6;« + »;« »))-VALEUR(SUBSTITUE(E6;« - »;« »))+VALEUR(SUBSTITUE(E12;« + »;« »))-VALEUR(SUBSTITUE(E12;« - »;« »))+VALEUR(SUBSTITUE(E18;« + »;« »))-VALEUR(SUBSTITUE(E18;« - »;« »))+VALEUR(SUBSTITUE(E24;« + »;« »))-VALEUR(SUBSTITUE(E24;« - »;« »))+VALEUR(SUBSTITUE(E30;« + »;« »))-VALEUR(SUBSTITUE(E30;« - »;« »)))

image
image492×680 10.7 KB

2

Bonjour,
Ne serait-il pas plus simple de partager directement le fichier concerné, puisque vous l’avez déjà sous la main ? Il est difficile d’identifier un problème et d’y apporter une solution en se basant uniquement sur une image
Slts

3

oui bien sur, pardon, le voici.

POINTAGE HORAIRE 2026.xlsx (113,8 Ko)

4

Bonjour,

La fonction VALEUR n’existe pas dans Excel. Quel tableur utilises-tu ?

Si tu veux transformer un nombre au format texte, essaie : VALEURNOMBRE.

Daniel

5

Essaie ceci en F32 :

=SOMME(VALEURNOMBRE(STXT(E4:E32;2;9^9)))

Daniel

[EDIT] Désolé, ça ne fonctionne pas avec des “-”.

6

J’ai mis “VALEURNOMBRE” partout et cette fois j’ai une nouvelle erreur “#VALEUR” qui s’affiche

7

on dirait bien que ça fonctionne, merci beaucoup, la seule chose c’est que je n’ai pas la couleur (vert si positif et rouge si négatif)

mais merci beaucoup, au moins j’ai un calcul qui s’effectue

8

Bonsoir,
POINTAGE HORAIRE 2026.xlsx (115,4 Ko)

Voir formule en F32 onglet FEVRIER 2026

=SI(SOMMEPROD(SI(E3:E32<>"";SI(GAUCHE(E3:E32;1)="-";-1;1)*TEMPSVAL(STXT(E3:E32;2;99));0))>=0;"+" & TEXTE(SOMMEPROD(SI(E3:E32<>"";SI(GAUCHE(E3:E32;1)="-";-1;1)*TEMPSVAL(STXT(E3:E32;2;99));0));"[h]:mm");"-" & TEXTE(ABS(SOMMEPROD(SI(E3:E32<>"";SI(GAUCHE(E3:E32;1)="-";-1;1)*TEMPSVAL(STXT(E3:E32;2;99));0)));"[h]:mm"))

et voir MFC pour la couleur rouge

=GAUCHE(F32;1)="-"

pour la couleur Verte

=GAUCHE(F32;1)="+"

Ps: Si tu ne veux pas voir dans l’onglet MODELE_2_SEMAINES " #VALEUR! " en C7 =SI(OU(C3="";C5="");"";C3+C5)
à la place de
=SI(NBVAL(C3;C5)=0;"";C3+C5) faire pareil pour les autres #VALEUR!

Slts

9

Bonjour à tous,

Essaie, pour tenir compte des valeurs négatives :

=SOMME(VALEURNOMBRE(SI(GAUCHE(E3:E32;1)="+";STXT(E3:E32;2;9^9);0)))-SOMME(VALEURNOMBRE(SI(GAUCHE(E3:E32;1)="-";STXT(E3:E32;2;9^9);0)))

Daniel

10

Un grand merci à tous !!! je vous souhaite un très bon week-end et encore merci <3