Supprimer cellules vides

Bonjour
Je sais que c’est un problème résolu et de plusieurs manières mais je n’arrive pas à appliquer les solutions o_0.

Alors voilà je souhaite que les valeurs d’une colonne se mettent a la suite.
S101
S102

S105

S101
S102
S105
Je n’ai pas besoin que les valeurs s’organisent mais juste que les espaces soient supprimés même en cas de changement des valeurs.

J’avais vu une solution avec formule matricielle mais je n’arrive pas à faire que ça fonctionne.
Quelqu’un pour m’aider?

Bonjour jiraiyasama,

En admettant que tes données soient en colonne A:

  • Pour compacter tes données avec doublons
    =SI(LIGNES($1:1)<=NBVAL($A$2:$A$9);INDEX($A$2:$A$9;PETITE.VALEUR(SI($A$2:$A$9<>"";LIGNE(INDIRECT("1:"&LIGNES($A$2:$A$9))));LIGNES($1:1)));"")
    ou
    =SIERREUR(SI(LIGNE()>NBVAL($A:$A);"";INDEX($A:$A;PETITE.VALEUR(SI(($A:$A<>"");($A:$A<>"")*LIGNE($A:$A));LIGNE())));"")
    Les $A:$A sont à changer par la colonne avec tes données
  • Pour compacter tes données sans doublons:
    =SIERREUR(INDEX($A$2:$A$9;MIN(SI(($A$2:$A$9<>"");SI(NB.SI($B$1:B1;$A$2:$A$9)=0;LIGNE($A$2:$A$9)-1;9^9))));0)
    Les $A$2:$A$9 sont à changer par ta plage de données (pas la colonne, mais bien la plage) et le $B$1:B1 par la lettre de colonne où tu appliques la formule (si tu la mets en C, ce sera $C$1:C1)

Les deux formules sont à valider avec CTRL+MAJ+ENTREE

Pour plus d’infos
http://boisgontierjacques.free.fr/pages_site/sommeprod.htm#ListeSansVide
Si tu as besoin d’explications sur le fonctionnement des formules, ça peut se faire :wink:

1 J'aime

Bonjour à tous,

Bonjour Nono, ta réponse est fonctionnelle, mais il ne faudrait pas avoir 3 à 4000 cellules, sinon, on peut presque aller boire un café.

Plus simple et rapide, (d’ailleurs on peut faire cette manip en enregistrant la macro)

Dans Excel, sélectionnez la colonne de votre tableau.
Pressez la touche F5 et appuyez sur le bouton Cellules.
Sélectionnez alors l’option Cellules vides et appuyez sur OK.
Les lignes vides sont alors sélectionnées.
Cliquez avec le bouton droit de la souris sur une cellule sélectionnée et choisissez la commande Supprimer.
Sélectionnez l’option Décaler les cellules vers le haut et cliquez sur OK.

1 J'aime

Re,

Bien vu @Mimimathy! C’est carrément plus simple et moins gourmand en ressources (mais comme j’aime bien le café, je trouve toujours des formules qui peuvent tout faire ramer🤣)

Bonsoir
Alors j’ai essayé la méthode à Mimimathy, qui ne fonctionne pas dans mon cas.
Je pense que c’est parce que mes cellules contiennent une formule.
Ce n’est pas bien grave puisque j’ai quand même réussi avec la méthode à Nono et que ça fonctionne très bien.
Merci à vous deux en tout cas.

1 J'aime

Ce sujet a été automatiquement fermé après 30 jours. Aucune réponse n’est permise dorénavant.