Recherche d'une combinaison de 3 valeurs pour trouver la boite adéquate à la pièce


#1

Nous aurions besoin d’aide SVP.
Mon collègue et moi travaillons sur un fichier nous permettant de déterminer la plus petite boîte possible dans une liste donnée à des références ayant des dimensions longueur, largeur et hauteur.
Le but est de trouver la boite la plus adaptée possible aux dimensions de la pièce

Nous mettons un fichier en exemple, si quelqu’un pourrait nous aider à le résoudre ce serait beaucoup de temps de gagner.
2 onglets :
Liste de références avec leurs dimensions
Liste des références cartons qui peuvent accueillir la référence

Par avance merciDemande Forum_Formules Excel.xlsx (22,1 Ko)


#2

Bonjour @CoralyPack,

Une proposition:

En “G3” a partir des 3 dimensions “L l h” on recherche la référence >= à “US” dans la feuille “Liste des boîtes”, puis on recherche la référence “Poids L l h” de la boîte correspondante, si pas de référence on écrit “No réf”.

En “G3” formule matricielle a valider par ctrl + maj + entrée

=SIERREUR(INDEX('Liste des boites'!$A$5:$A$126;EQUIV(1;('Liste des boites'!$C$5:$C$126>=B3)*('Liste des boites'!$D$5:$D$126>=C3)*('Liste des boites'!$E$5:$E$126>=D3);0));"No réf")

En “H3”

=SIERREUR(RECHERCHEV($G3;'Liste des boites'!$A:$E;2;0);"No réf")

En “I3”

=SIERREUR(RECHERCHEV($G3;'Liste des boites'!$A:$E;3;0);"No réf")

En “J3”

=SIERREUR(RECHERCHEV($G3;'Liste des boites'!$A:$E;4;0);"No réf")

En “K3”

=SIERREUR(RECHERCHEV($G3;'Liste des boites'!$A:$E;5;0);"No réf")

Ci-joint le fichier en retour ICI==> CoralyPack V1.xlsx (30,4 Ko)

Cordialement.


#3

Bonjour,

Merci pour votre retour et votre réactivité.

Nous avons travaillé dessus tout aujourd’hui, et cela répond complètement à nos besoins.

Encore merci pour votre aide…

Bonne continuation
Cordialement

-------- Message d’origine --------