Obtention d'informations à partir d'une zone de liste déroulante


#1

Bonjour à tous les contributeurs de ce site,

je voudrais à partir d’une zone de liste déroulante (feuil3-TDB), disposer des informations ( Age , nom et Entité de rattachement) pour chacune des entités , informations extraites à partir du fichier source (Feuil1).

Merçi d’avance à Tous.
Fichier 13-06-2017.xlsx (162,2 Ko)


#2

Bonsoir @molo,

Voici une proposition:

Dans la feuille “Calculs”.
En “E3”:

=SI(TDB!$A$2="Entreprise";SOMMEPROD(MAX((Entreprise=TDB!$A$2)*(age)));SOMMEPROD(MAX((Entités=TDB!$A$2)*(age))))

En “F3”:

=INDEX(Fichiersource!$B$2:$B$745;EQUIV(E3;Fichiersource!$H$2:$H$745;0))

En “G3”:

=INDEX(Fichiersource!$F$2:$F$745;EQUIV(E3;Fichiersource!$H$2:$H$745;0))

En “E4”

=SI(TDB!$A$2="Entreprise";SOMMEPROD(MAX((Entreprise=TDB!$A$2)*(anciennete)));SOMMEPROD(MAX((Entités=TDB!$A$2)*(anciennete))))

En “F4”:

=INDEX(Fichiersource!$B$2:$B$745;EQUIV(E4;Fichiersource!$J$2:$J$745;0))

En “G4”:

=INDEX(Fichiersource!$F$2:$F$745;EQUIV(E4;Fichiersource!$J$2:$J$745;0))

Les résultats sont dans la feuille “TDB”

Ci-joint le fichier ICI==> molo V1.xlsx (177,0 Ko)

Cordialement.


#3

Bonjour @molo,

Après une nuit de repos, je viens de m’apercevoir qu’il fallait procéder de la même manière que la dernière fois, a savoir ajouter des colonnes “Ajuster Âge” & “Ajuster Ancienneté” car il y a des doublons.

Donc voir dans le “Gestionnaire de noms”.
Les 2 colonnes ajoutées dans la feuille “Fichiersource”

En “I2” =[@[Age ]]+LIGNE()*0,00000001 et tirer vers le bas.
En “L2” =[@Ancienneté]+LIGNE()*0,00000001 et tirer vers le bas.

Dans la feuille “Calculs”.

En “D3” formule matricielle a valider avec ctrl + maj + entrée:

{=SIERREUR(SI(TDB!$A$2="Entreprise";GRANDE.VALEUR(SI((Entreprise=TDB!$A$2);Ajuster_Âge);1);GRANDE.VALEUR(SI((Entités=TDB!$A$2);Ajuster_Âge);1));"")}

En “E3”:

=INDEX(Ajuster_Ancienneté;EQUIV($D$3;Ajuster_Âge;0))

En “F3”:

=INDEX(nomprenom;EQUIV($D$3;Ajuster_Âge;0))

En “G3”:

=INDEX(Entités;EQUIV($D$3;Ajuster_Âge;0))

En “D4”:

=INDEX(Ajuster_Âge;EQUIV($E$4;Ajuster_Ancienneté;0))

En "E4"formule matricielle a valider avec ctrl + maj + entrée:

{=SIERREUR(SI(TDB!$A$2="Entreprise";GRANDE.VALEUR(SI((Entreprise=TDB!$A$2);Ajuster_Ancienneté);1);GRANDE.VALEUR(SI((Entités=TDB!$A$2);Ajuster_Ancienneté);1));"")}

En “F4”:

=INDEX(nomprenom;EQUIV($E$4;Ajuster_Ancienneté;0))

En “G4”:

=INDEX(Entités;EQUIV($E$4;Ajuster_Ancienneté;0))

Résultats dans la feuille “TDB”.

Et le fichier mis a jour ICI==> molo V2.xlsx (206,6 Ko)

Cordialement.


#4

Bonjour mdo100

Merçi pour la performance

Cordiales salutations