FAQ: Comment récupérer le numéro de la derniere ligne non vide


#1

Bonjour
Une question fréquemment posée sur Excel:

Comment récupérer le numéro de la derniere ligne non vide sur Excel?
En VBA ou avec une formule?


#2

1) Avec une macro
Le code suivant affecte le numero de la derniere ligne non vide de la colonne A dans la variable DerniereLigne

Dim DerniereLigne As Long 
DerniereLigne = Range("A" & Rows.Count).End(xlUp).Row

Fonctionnement: On part de la derniere cellule de la colonne A, puis on fait defiler automatiquement (VBA s’aerrete a la premiere cellule non vide en partant du bas)
Cela correspond a la derniere cellule non vide en partant du haut

2) Avec une formule
Attention, formule matricielle ( A valider avec CTRL + MAJ + ENTREE ) afin que les accolades {} apparaissent et que la formule soit prise en compte correctement

{=MAX(SI(ESTVIDE(A:A);0;LIGNE(A:A)))}

Fonctionnement: pour chaque cellule de la colonne A, on renvoie 0 si la cellule est vide et le numero de la ligne si elle est non-vide. Puis on prend le MAX de tout cela, qui sera donc le numero de la derniere cellule non vide


#3

Bonjour @DocteurExcel, toutes et tous,

Un complément pour récupérer le numéro de la dernière ligne non vide de la colonne “A” par formule normale:

Si dans la colonne “A” nous avons des valeurs Alphanumériques et que l’on veut récupérer le numéro de la dernière ligne non vide Alphabétique.

Alors on peut écrire cette formule avec le préfixe “Ligne”:

="Ligne"&" "&SIERREUR(EQUIV("zzz";A:A;1);0)

Si nous voulons récupérer le numéro de la dernière ligne non vide Numérique.

Alors on peut écrire cette formule avec le préfixe “Ligne”:

="Ligne"&" "&MAX(SIERREUR(EQUIV(9^9;A:A;1);0))

Si nous voulons récupérer le numéro de la dernière ligne non vide AlphaNumérique.

Alors nous fusionnons les 2 formules ci-dessus avec le préfixe “Ligne”:

="Ligne"&" "&MAX(SIERREUR(EQUIV(9^9;A:A;1);0);SIERREUR(EQUIV("zzz";A:A;1);0))

Bien sûr le préfixe peut-être supprimé en supprimant dans les formules cette partie:

“Ligne”&" "& dans ce cas il n’y aura que le numéro de ligne.

Voici un petit fichier pour illustrer les explications ci-dessus ICI==> Dernière Ligne Non Vide Alpha-Numérique.xlsx (10,5 Ko)

Bon courage à toutes et tous.

Cordialement.


#4

4 messages ont été déplacés vers un nouveau sujet : Intégrer le numéro de la derniere ligne non vide dans une formule